liyepan
caa65b9c97
- 从 logo.png 生成 packaging/ 下的 ico / icns / 256px png - Qt 运行时窗口图标走 resources.qrc（不安装也有图标）， 并以 setDesktopFileName 声明桌面文件名 - Linux 增加 voiletmark.desktop 与 make install 规则 （可执行文件 + desktop 条目 + hicolor 图标） - Windows 用 RC_ICONS 嵌入 exe 图标，macOS 用 ICON 设置 app bundle 图标 - 关于对话框显示 logo - 版本 0.3.1
42 lines
1005 B
Prolog
42 lines
1005 B
Prolog
TEMPLATE = app
|
|
TARGET = VoiletMark
|
|
VERSION = 0.3.1
|
|
|
|
QT += core gui widgets
|
|
|
|
CONFIG += c++17 warn_on
|
|
|
|
# 让 main.cpp 里的 QStringLiteral(VM_VERSION) 拿到版本号字符串
|
|
DEFINES += VM_VERSION=\\\"$$VERSION\\\"
|
|
|
|
INCLUDEPATH += $$PWD/src
|
|
|
|
RESOURCES += resources.qrc
|
|
|
|
# 各平台的可执行文件图标
|
|
win32: RC_ICONS = packaging/voiletmark.ico
|
|
macx: ICON = packaging/voiletmark.icns
|
|
|
|
SOURCES += \
|
|
src/main.cpp \
|
|
src/MainWindow.cpp \
|
|
src/MarkdownEditor.cpp \
|
|
src/MarkdownHighlighter.cpp \
|
|
src/ThemeManager.cpp
|
|
|
|
HEADERS += \
|
|
src/MainWindow.h \
|
|
src/MarkdownEditor.h \
|
|
src/MarkdownHighlighter.h \
|
|
src/ThemeManager.h
|
|
|
|
# Linux 桌面集成：make install 之后能在应用菜单里找到
|
|
isEmpty(PREFIX): PREFIX = /usr/local
|
|
|
|
target.path = $$PREFIX/bin
|
|
desktop.files = packaging/voiletmark.desktop
|
|
desktop.path = $$PREFIX/share/applications
|
|
icon.files = packaging/voiletmark.png
|
|
icon.path = $$PREFIX/share/icons/hicolor/256x256/apps
|
|
INSTALLS += target desktop icon
|