liyepan
505063a2e7
- 顶部工具栏：新建 / 打开 / 保存，以及「最近文件」「最近目录」下拉菜单 - 文件菜单同样拆成「最近文件」「最近目录」两个子菜单，各记 8 条、可分别清空 - 启动时自动打开上次编辑的文件，文件不存在则显示欢迎文档 - 所有设置改用 AppConfig 单例写进同一个 config.ini；关于对话框显示其路径 - 修掉编辑器一创建就被标成「已修改」的问题（setDocumentMargin 的副作用）， 否则恢复上次文件时会误弹保存提示 - 工具栏加了配套的 QSS 与中英文翻译，截图更新到 0.12.0
52 lines
1.2 KiB
Prolog
52 lines
1.2 KiB
Prolog
TEMPLATE = app
|
|
TARGET = VoiletMark
|
|
VERSION = 0.12.0
|
|
|
|
QT += core gui widgets
|
|
|
|
CONFIG += c++17 warn_on
|
|
|
|
# 让 main.cpp 里的 QStringLiteral(VM_VERSION) 拿到版本号字符串
|
|
DEFINES += VM_VERSION=\\\"$$VERSION\\\"
|
|
|
|
INCLUDEPATH += $$PWD/src
|
|
|
|
RESOURCES += resources.qrc
|
|
|
|
# 各平台的可执行文件图标
|
|
win32: RC_ICONS = packaging/voiletmark.ico
|
|
macx: ICON = packaging/voiletmark.icns
|
|
|
|
SOURCES += \
|
|
src/main.cpp \
|
|
src/MainWindow.cpp \
|
|
src/MarkdownEditor.cpp \
|
|
src/MarkdownHighlighter.cpp \
|
|
src/MarkdownRenderer.cpp \
|
|
src/AppConfig.cpp \
|
|
src/CodeHighlight.cpp \
|
|
src/GitRunner.cpp \
|
|
src/LanguageManager.cpp \
|
|
src/ThemeManager.cpp
|
|
|
|
HEADERS += \
|
|
src/MainWindow.h \
|
|
src/MarkdownEditor.h \
|
|
src/MarkdownHighlighter.h \
|
|
src/MarkdownRenderer.h \
|
|
src/AppConfig.h \
|
|
src/CodeHighlight.h \
|
|
src/GitRunner.h \
|
|
src/LanguageManager.h \
|
|
src/ThemeManager.h
|
|
|
|
# Linux 桌面集成：make install 之后能在应用菜单里找到
|
|
isEmpty(PREFIX): PREFIX = /usr/local
|
|
|
|
target.path = $$PREFIX/bin
|
|
desktop.files = packaging/voiletmark.desktop
|
|
desktop.path = $$PREFIX/share/applications
|
|
icon.files = packaging/voiletmark.png
|
|
icon.path = $$PREFIX/share/icons/hicolor/256x256/apps
|
|
INSTALLS += target desktop icon
|