liyepan
2f8726ad47
- 导出预览窗口按屏幕可用高度计算尺寸，底部的「保存 PDF…」不会再顶出屏幕 - 默认欢迎文档去掉「实时预览（下一版）」，换成已实现的导出 PDF - logo 是黑字透明底，放深色任务栏里等于看不见；packaging/generate_icons.py 给它垫白色圆角底板并输出 16–256 多尺寸 ico，窗口图标与 exe 图标统一使用 - 新增 packaging/generate_icons.py，便于换图后重新生成 - 文档与截图同步
46 lines
1.1 KiB
Prolog
46 lines
1.1 KiB
Prolog
TEMPLATE = app
|
|
TARGET = VoiletMark
|
|
VERSION = 0.5.1
|
|
|
|
QT += core gui widgets printsupport
|
|
|
|
CONFIG += c++17 warn_on
|
|
|
|
# 让 main.cpp 里的 QStringLiteral(VM_VERSION) 拿到版本号字符串
|
|
DEFINES += VM_VERSION=\\\"$$VERSION\\\"
|
|
|
|
INCLUDEPATH += $$PWD/src
|
|
|
|
RESOURCES += resources.qrc
|
|
|
|
# 各平台的可执行文件图标
|
|
win32: RC_ICONS = packaging/voiletmark.ico
|
|
macx: ICON = packaging/voiletmark.icns
|
|
|
|
SOURCES += \
|
|
src/main.cpp \
|
|
src/MainWindow.cpp \
|
|
src/MarkdownEditor.cpp \
|
|
src/MarkdownHighlighter.cpp \
|
|
src/MarkdownRenderer.cpp \
|
|
src/ExportDialog.cpp \
|
|
src/ThemeManager.cpp
|
|
|
|
HEADERS += \
|
|
src/MainWindow.h \
|
|
src/MarkdownEditor.h \
|
|
src/MarkdownHighlighter.h \
|
|
src/MarkdownRenderer.h \
|
|
src/ExportDialog.h \
|
|
src/ThemeManager.h
|
|
|
|
# Linux 桌面集成：make install 之后能在应用菜单里找到
|
|
isEmpty(PREFIX): PREFIX = /usr/local
|
|
|
|
target.path = $$PREFIX/bin
|
|
desktop.files = packaging/voiletmark.desktop
|
|
desktop.path = $$PREFIX/share/applications
|
|
icon.files = packaging/voiletmark.png
|
|
icon.path = $$PREFIX/share/icons/hicolor/256x256/apps
|
|
INSTALLS += target desktop icon
|